Email: info@sixcolor.com.cn | Call:  4006 586 306

最全的DOS批处理命令：自动删除指定天数日期之前的文件

【方案一】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + REG + VBS

  1. @echo off
  2. ::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
  4. ::本例调用了临时VBS代码进行日期计算
  5. ::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
  6. ::处理完毕之后再把日期格式恢复成原来的状态。
  7.  
  8. rem 指定待删除文件的存放路径
  9. set SrcDir=C:\Test\BatHome
  10. rem 指定天数
  11. set DaysAgo=1
  12. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  13.     set "RegDateOld=%%a"
  14. )
  15. set RegDateOld=%RegDateOld:~-8%
  16. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  17. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  18. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  19. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  20. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  21.     set "DstDate=%%a"
  22. )
  23. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  24. for /r "%SrcDir%" %%a in (*.*) do (
  25.     if "%%~ta" leq "%DstDate%" (
  26.         if exist "%%a" (
  27.             echo del /f /q "%%a"
  28.         )
  29.     )
  30. )
  31. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  32. pause

【方案二】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + REG + Ritchie Lawrence 日期函数

  1. @echo off
  2. ::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
  4. ::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
  5. ::日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
  6. ::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
  7. ::处理完毕之后再把日期格式恢复成原来的状态。
  8.  
  9. rem 指定待删除文件的存放路径
  10. set SrcDir=C:\Test\BatHome
  11. rem 指定天数
  12. set DaysAgo=1
  13. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  14.     set "RegDateOld=%%a"
  15. )
  16. set RegDateOld=%RegDateOld:~-8%
  17. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  18. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
  19. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  20. set /a PassDays-=%DaysAgo%
  21. call :DaysToDate %PassDays% DstYear DstMonth DstDay
  22. set DstDate=%DstYear%-%DstMonth%-%DstDay%
  23. for /r "%SrcDir%" %%a in (*.*) do (
  24.     if "%%~ta" leq "%DstDate%" (
  25.         if exist "%%a" (
  26.             echo del /f /q "%%a"
  27.         )
  28.     )
  29. )
  30. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  31. pause
  32. goto :eof
  33.  
  34. :DateToDays %yy% %mm% %dd% days
  35. setlocal ENABLEEXTENSIONS
  36. set yy=%1&set mm=%2&set dd=%3
  37. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  38. set /a dd=100%dd%%%100,mm=100%mm%%%100
  39. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
  40. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
  41. endlocal&set %4=%j%&goto :EOF
  42.  
  43. :DaysToDate %days% yy mm dd
  44. setlocal ENABLEEXTENSIONS
  45. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
  46. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
  47. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
  48. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
  49. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

【方案三】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + VBS

  1. @echo off
  2. ::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
  4. ::本例调用了临时VBS代码进行日期计算，并统一设置系统日期格式，处理完毕
  5. ::之后再把日期格式恢复成原来的状态。摆脱了对reg命令（XP系统自带）的依赖。
  6.  
  7. rem 指定待删除文件的存放路径
  8. set SrcDir=C:\Test\BatHome
  9. rem 指定天数
  10. set DaysAgo=1
  11. >"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  12. >>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
  13. for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
  14.     set "RegDateOld=%%a"
  15. )
  16. >"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  17. >>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
  18. cscript /nologo "%temp%\UnifyDate.vbs"
  19. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  20. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  21. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  22. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  23.     set "DstDate=%%a"
  24. )
  25. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  26. for /r "%SrcDir%" %%a in (*.*) do (
  27.     if "%%~ta" leq "%DstDate%" (
  28.         if exist "%%a" (
  29.             echo del /f /q "%%a"
  30.         )
  31.     )
  32. )
  33. >"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  34. >>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
  35. cscript /nologo "%temp%\RecoverDate.vbs"
  36. pause

【方案四】删除指定路径下指定天数之前（以文件的创建日期为准）的文件：BAT + REG + Ritchie Lawrence 日期函数

  1. @echo off
  2. ::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。
  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
  4. ::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
  5. ::日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
  6. ::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
  7. ::处理完毕之后再把日期格式恢复成原来的状态。
  8.  
  9. rem 指定待删除文件的存放路径
  10. set SrcDir=C:\Test\BatHome
  11. rem 指定天数
  12. set DaysAgo=1
  13. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  14.     set "RegDateOld=%%a"
  15. )
  16. set RegDateOld=%RegDateOld:~-8%
  17. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  18. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
  19. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  20. set /a PassDays-=%DaysAgo%
  21. call :DaysToDate %PassDays% DstYear DstMonth DstDay
  22. set DstDate=%DstYear%-%DstMonth%-%DstDay%
  23.  
  24. for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
  25.     call :CompareTime "%%a"
  26. )
  27. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  28. pause
  29. goto :eof
  30.  
  31. :DateToDays %yy% %mm% %dd% days
  32. setlocal ENABLEEXTENSIONS
  33. set yy=%1&set mm=%2&set dd=%3
  34. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  35. set /a dd=100%dd%%%100,mm=100%mm%%%100
  36. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
  37. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
  38. endlocal&set %4=%j%&goto :EOF
  39.  
  40. :DaysToDate %days% yy mm dd
  41. setlocal ENABLEEXTENSIONS
  42. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
  43. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
  44. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
  45. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
  46. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
  47.  
  48. :CompareTime
  49. for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
  50.     if "%%h" leq "%DstDate%" (
  51.         if exist %1 (
  52.             echo del /a /f /q %1
  53.         )
  54.     )
  55.     goto :eof
  56. )

【方案五】删除指定路径下指定天数之前（以文件的修改日期为准）的文件：forfiles

  1. @echo off
  2. ::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
  4. ::本例需要Win2003/Vista/Win7系统自带的forfiles命令的支持
  5.  
  6. rem 指定待删除文件的存放路径
  7. set SrcDir=C:\Test\BatHome
  8. rem 指定天数
  9. set DaysAgo=1
  10.  
  11. forfiles /p %SrcDir% /s /m *.* /d -%DaysAgo% /c "cmd /c echo del /f /q /a @path"
  12. pause
     

【方案六】删除指定路径下指定天数之前（以文件名中包含的日期字符串为准）的文件：字符串截取

  1. @echo off
  2. ::演示：删除指定路径下指定天数之前（以文件名中包含的日期字符串为准）的文件。
  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
  4. ::本例假设文件名中包含的日期字符串（比如：bak-2009-12-25.log）
  5.  
  6. rem 指定待删除文件的存放路径
  7. set SrcDir=C:\Test\BatHome
  8. rem 指定天数
  9. set DaysAgo=1
  10.  
  11. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  12. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  13. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  14. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  15.   set "DstDate=%%a"
  16. )
  17. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  18.  
  19. setlocal enabledelayedexpansion
  20. for /r "%SrcDir%" %%a in (*.*) do (
  21.     set "FileDate=%%~na"
  22.     set "FileDate=!FileDate:~4,10!"
  23.     if "!FileDate!" leq "%DstDate%" (
  24.         if exist "%%a" (
  25.             echo del /f /q "%%a"
  26.         )
  27.     )
  28. )
  29. endlocal
  30. pause

客服电话:  +86 (0)20 2332 6688# 0(5条线)
业务咨询:  4006 586 306 | +86 (0)20 8656 8011 # 0
咨询邮箱:  info@sixcolor.com.cn
投诉邮箱:  complaints@sixcolor.com.cn
英文邮箱:  english@sixcolor.com.cn
地        址:  广东省广州市白云区金易街11号岭南V谷3栋

扫一扫 关注公众号

微信扫描关sixcolor公众号

Copyright © 2008-2020 广州陆彩软件科技有限公司 | 粤ICP备15065631号-2